Valor selecionado em um TSlider

Framework - Linha Protheus LIB
,
1

Alguém sabe como obter o valor selecionado pelo usuário em um objeto da classe TSlider?

2

Cesar,

O valor selecionado é informado na alteração o componente TSlider, logo você precisa implementar um bloco de bChange.

No exemplo abaixo, eu trabalho com o valor do TSlider na variável nValue:


#include "protheus.ch"

//-------------------------------------------------------------------
/*/{Protheus.doc} ValueTSlider
Verificação de valor do TSlider

@author Daniel Mendes
@since 11/01/2023
@version 1.0
/*/
//-------------------------------------------------------------------
user function ValueTSlider()
local oDlg as object
local oSlider as object
local oBtn as object
local nValue as numeric

nValue := 0

oDlg = TDialog():New( 180, 180, 310, 700, "Exemplo TSlider",,, .F.,,,,,, .T.,,,,, )

oSlider := TSlider():New( 01, 01, oDlg, {|x| Iif(x == nil, nil, nValue := x)}, 260, 30, "Mensagem")

oBtn := TButton():New( 40, 95, "Valor do TSlider",oDlg, {||MsgInfo("O valor atual do TSlider é de " + cValToChar(nValue), "TOTVS")}, 60, 10,,, .F., .T., .F.,, .F.,,, .F. )

oDlg:Activate(,,, .T.,,,,,)

MsgInfo("O valor final do TSlider foi de " + cValToChar(nValue), "TOTVS")

return

Documentação: https://tdn.totvs.com/display/tec/TSlider