MPFormModel com pesquisa

Framework - Linha Protheus LIB
,
1

Bom dia,

Tem como habilitar a pesquisa da dados na classe MPFormModel, gostaria de utilizar o filtro ou buscar das informações inseridas pelo usuário.

2

Bom dia!

A pesquisa que você se refere seria no grid ou dentro do formulário de cadastro?

No formulário de cadastro acredito que o único filtro/pesquisa disponível é a pesquisa de campos utilizando o atalho Control + F. Ele é ativado por padrão.

Já no grid é possível habilitar o filtro/pesquisa, é necessário configurar as propriedades GRIDSEEK e GRIDFILTER na ViewDef do seu programa:


Static Function ViewDef
Local oView            := Nil
Local oStructCalc    := Nil
Local oModel        := FwLoadModel('ELFATA46')
Local oStructZF5    := FwFormStruct(2, 'ZF5')
Local oStructZF6    := FwFormStruct(2, 'ZF6')

    oView := FwFormView():New() 

    oStructCalc := FwCalcStruct(oModel:GetModel('ModelCalc'))

    oView:SetModel(oModel)

    oView:AddField('ViewZF5', oStructZF5, 'FormZF5')
    oView:AddGrid('ViewZF6', oStructZF6, 'GridZF6')
    oView:AddField('ViewCalc', oStructCalc, 'ModelCalc')

    //Força o uso da nova grid
    oView:SetViewProperty('ViewZF6', 'ENABLENEWGRID')

    //Desabilita a ordenação da grid 
    oView:SetViewProperty('ViewZF6', 'GRIDNOORDER')

    //Habilita o uso do filtro 
    oView:SetViewProperty('ViewZF6', 'GRIDFILTER', { .T. })

    //Habilita o uso da pesquisa 
    oView:SetViewProperty('ViewZF6', 'GRIDSEEK', { .T. })

    oView:CreateHorizontalBox('MAIN', 040)
    oView:CreateHorizontalBox('GRID', 045)
    oView:CreateHorizontalBox('RODAPE', 015)

    oView:EnableTitleView('ViewZF5', 'Informações do Pedido de Venda')
    oView:EnableTitleView('ViewZF6', 'Produtos do Pedido de Venda')
    oView:EnableTitleView('ViewCalc', 'Totalizadores')

    oView:SetOwnerView('ViewZF5', 'MAIN')
    oView:SetOwnerView('ViewZF6', 'GRID')
    oView:SetOwnerView('ViewCalc', 'RODAPE')

    oView:SetInsertMessage('Integração de Pedidos de Venda', 'Pedido inserido com sucesso!')
    oView:SetUpdateMessage('Integração de Pedidos de Venda', 'Pedido alterado com sucesso!')
    oView:SetDeleteMessage('Integração de Pedidos de Venda', 'Pedido excluído com sucesso!')

Return(oView)
3

Bom dia,
Muito obrigado ajudou muito , gostaria mesmo do GRIDFILTER , só não encontrava , ficou perfeito;